Editing HyperTalk (section)

===Handling text===
A notable feature of the HyperTalk container model was its handling of text. Every collection of text, whether a literal string in a program or text typed into a text field, was itself considered a container with multiple collections of containers within it. This allowed scripts to parse text using the same navigational commands as any other container. For instance, while parsing a space-delimited data file, one might want to extract the third column, like this:
<syntaxhighlight lang="applescript">
  put the third word of theFilesText into colThree
</syntaxhighlight>
This syntax allowed the script to "walk" down the text to find particular data, as in this example:
<syntaxhighlight lang="applescript">
   put the first character of the third word of line 5 of card field "sometext" into theChar
</syntaxhighlight>
This process of treating text as a container was known as "chunking", and the functions as "chunk expressions". These same sorts of expressions were used to handle file manipulation, along with a set of file management functions. The following code opens a known file, reads from it, extracts data, and then closes the file:
<syntaxhighlight lang="applescript">
  on mouseDown
    answer file "Please select a text file to open."
    if it is empty then exit mouseDown
    put it into filePath
    if there is a file filePath then
      open file filePath
      read from file filePath until return
      put it into cd fld "some field"
      close file filePath
      set the textStyle of character 1 to 10 of card field "some field" to bold
    end if
  end mouseDown
</syntaxhighlight>
HyperTalk also included functions for chunking strings using a substring-find operation using the <code>in</code> operator. The following code finds all examples of a given pattern using the <code>in</code> as part of the <code>repeat</code> loop, while <code>offset</code> finds the location of that pattern within the string:
<syntaxhighlight lang="applescript" highlight="1">
  function replaceStr pattern,newStr,inStr
    repeat while pattern is in inStr
      put offset(pattern,inStr) into pos
      put newStr into character pos to (pos +the length of pattern)-1 of inStr
    end repeat
    return inStr
  end replaceStr
</syntaxhighlight>