Editing ML (programming language) (section)

==Examples==
The following examples use the syntax of Standard ML. Other ML dialects such as OCaml and F# differ in small ways.

===Factorial===
The [[factorial]] function expressed as pure ML:

<syntaxhighlight lang="sml">
fun fac (0 : int) : int = 1
  | fac (n : int) : int = n * fac (n - 1)
</syntaxhighlight>

This describes the factorial as a recursive function, with a single terminating base case. It is similar to the descriptions of factorials found in mathematics textbooks. Much of ML code is similar to mathematics in facility and syntax.

Part of the definition shown is optional, and describes the ''types'' of this function. The notation E : t can be read as ''expression E has type t''. For instance, the argument n is assigned type ''integer'' (int), and fac (n : int), the result of applying fac to the integer n, also has type integer. The function fac as a whole then has type ''function from integer to integer'' (int -> int), that is, fac accepts an integer as an argument and returns an integer result. Thanks to type inference, the type annotations can be omitted and will be derived by the compiler. Rewritten without the type annotations, the example looks like:

<syntaxhighlight lang="sml">
fun fac 0 = 1
  | fac n = n * fac (n - 1)
</syntaxhighlight>

The function also relies on pattern matching, an important part of ML programming. Note that parameters of a function are not necessarily in parentheses but separated by spaces. When the function's argument is 0 (zero) it will return the integer 1 (one). For all other cases the second line is tried. This is the [[Recursion (computer science)|recursion]], and executes the function again until the base case is reached.

This implementation of the factorial function is not guaranteed to terminate, since a negative argument causes an [[infinite descending chain]] of recursive calls. A more robust implementation would check for a nonnegative argument before recursing, as follows:

<syntaxhighlight lang="sml">
fun fact n = let
  fun fac 0 = 1
    | fac n = n * fac (n - 1)
  in
    if (n < 0) then raise Domain else fac n
  end
</syntaxhighlight>

The problematic case (when n is negative) demonstrates a use of ML's exception system.

The function can be improved further by writing its inner loop as a [[tail call]], such that the [[call stack]] need not grow in proportion to the number of function calls. This is achieved by adding an extra, ''accumulator'', parameter to the inner function. At last, we arrive at

<syntaxhighlight lang="sml">
fun fact n = let
  fun fac 0 acc = acc
    | fac n acc = fac (n - 1) (n * acc)
  in
    if (n < 0) then raise Domain else fac n 1
  end
</syntaxhighlight>

===List reverse===
The following function ''reverses'' the elements in a list. More precisely, it returns a new list whose elements are in reverse order compared to the given list.

<syntaxhighlight lang="sml">
fun reverse [] = []
  | reverse (x :: xs) = (reverse xs) @ [x]
</syntaxhighlight>

This implementation of reverse, while correct and clear, is inefficient, requiring [[quadratic time]] for execution. The function can be rewritten to execute in [[linear time]]:

<syntaxhighlight lang="sml">
fun 'a reverse xs : 'a list = List.foldl (op ::) [] xs
</syntaxhighlight>
This function is an example of parametric polymorphism. That is, it can consume lists whose elements have any type, and return lists of the same type.

===Modules===
Modules are ML's system for structuring large projects and libraries. A module consists of a signature file and one or more structure files. The signature file specifies the [[API]] to be implemented (like a C header file, or [[Interface (Java)|Java interface]] file). The structure implements the signature (like a C source file or Java class file). For example, the following define an Arithmetic signature and an implementation of it using Rational numbers:

<syntaxhighlight lang="sml">
signature ARITH =
sig
        type t
        val zero : t
        val succ : t -> t
        val sum : t * t -> t
end
</syntaxhighlight>

<syntaxhighlight lang="sml">
structure Rational : ARITH =
struct
        datatype t = Rat of int * int
        val zero = Rat (0, 1)
        fun succ (Rat (a, b)) = Rat (a + b, b)
        fun sum (Rat (a, b), Rat (c, d)) = Rat (a * d + c * b , b * d)
end
</syntaxhighlight>

These are imported into the interpreter by the 'use' command. Interaction with the implementation is only allowed via the signature functions, for example it is not possible to create a 'Rat' data object directly via this code. The 'structure' block hides all the implementation detail from outside.

ML's standard libraries are implemented as modules in this way.