Editing Forth (programming language) (section)

=== RC4 cipher program ===
In 1987, [[Ron Rivest]] developed the [[RC4]] cipher-system for RSA Data Security, Inc. Its description follows:

{{Blockquote|We have an array of 256 bytes, all different. Every time the array is used it changes by swapping two bytes. The swaps are controlled by counters ''i'' and ''j'', each initially 0. To get a new ''i'', add 1. To get a new ''j'', add the array byte at the new ''i''. Exchange the array bytes at ''i'' and ''j''. The code is the array byte at the sum of the array bytes at ''i'' and ''j''. This is XORed with a byte of the plaintext to encrypt, or the ciphertext to decrypt. The array is initialized by first setting it to 0 through 255. Then step through it using ''i'' and ''j'', getting the new ''j'' by adding to it the array byte at ''i'' and a key byte, and swapping the array bytes at ''i'' and ''j''. Finally, ''i'' and ''j'' are set to 0. All additions are modulo 256.}}

The following Standard Forth version uses Core and Core Extension words only.

<syntaxhighlight lang="forth">
0 value ii        0 value jj
0 value KeyAddr   0 value KeyLen
create SArray   256 allot   \ state array of 256 bytes
: KeyArray      KeyLen mod   KeyAddr ;

: get_byte      + c@ ;
: set_byte      + c! ;
: as_byte       255 and ;
: reset_ij      0 TO ii   0 TO jj ;
: i_update      1 +   as_byte TO ii ;
: j_update      ii SArray get_byte +   as_byte TO jj ;
: swap_s_ij
    jj SArray get_byte
       ii SArray get_byte  jj SArray set_byte
    ii SArray set_byte
;

: rc4_init ( KeyAddr KeyLen -- )
    256 min TO KeyLen   TO KeyAddr
    256 0 DO   i i SArray set_byte   LOOP
    reset_ij
    BEGIN
        ii KeyArray get_byte   jj +  j_update
        swap_s_ij
        ii 255 < WHILE
        ii i_update
    REPEAT
    reset_ij
;
: rc4_byte
    ii i_update   jj j_update
    swap_s_ij
    ii SArray get_byte   jj SArray get_byte +   as_byte SArray get_byte  xor
;
</syntaxhighlight>

This is one way to test the code:
<syntaxhighlight lang="forth">
hex
create AKey   61 c, 8A c, 63 c, D2 c, FB c,
: test   cr   0 DO  rc4_byte . LOOP  cr ;
AKey 5 rc4_init
2C F9 4C EE DC  5 test   \ output should be: F1 38 29 C9 DE
</syntaxhighlight>